論理演算

5-7.練習問題

キーボードから１文字入力し、アルファベットならば大文字に変換して表示するプログラムを作れ。ただしリターンキーが押されるまで繰り返す。
キーボードから１文字入力し、アルファベットの大文字なら小文字に、小文字なら大文字に変換して表示するプログラムを作れ。ただしリターンキーが押されるまで繰り返す。

ヒント

キーが入力されても表示されては困る(エコーバックしない)。以前紹介したが、今回も「AH=8」を使用する。(入力文字はALに返される)
'A'～'Z'の文字コードは41h～5Ah。'a'～'z'の文字コードは61h～7ah。20h分の差がある。「SUB」命令、「ADD」命令使うの方法もあるが、今回は論理演算を用いる。
リターンキーが押されると、AL=0Dhが返される。

解答1:大文字に変換

CODE	SEGMENT
	ASSUME	DS:CODE,CS:CODE,ES:CODE,SS:CODE
	.186
	ORG	100h

START:
	mov	ah,8
	int	21h		;文字入力

	cmp	al,0dh
	jz	EXIT		;リターンキーなら終了

	cmp	al,'a'		;↓小文字かどうかのチェック
	jb	DISP
	cmp	al,'z'
	ja	DISP		;↑ここまで

	and	al,11011111b	;to upper charactar

DISP:
	mov	dl,al
	mov	ah,2
	int	21h		;表示

	jmp	short START

EXIT:
	mov	ax,4c00h
	int	21h		;終了

	ENDS
	END	START
; 一部のコンパイラでは、
;CODE	ENDS
;	END	START
;と記述しなければいけないようです

解答2:大文字、小文字を逆転

CODE	SEGMENT
	ASSUME	DS:CODE,CS:CODE,ES:CODE,SS:CODE
	.186
	ORG	100h

START:
	mov	ah,8
	int	21h		;文字入力

	cmp	al,0dh
	jz	EXIT		;リターンキーなら終了

	cmp	al,'A'		;↓アルファベットかどうかのチェック
	jb	DISP
	cmp	al,'Z'
	jbe	XCHANGE
	cmp	al,'a'
	jb	DISP
	cmp	al,'z'
	ja	DISP		;↑ここまで
XCHANGE:
	xor	al,00100000b	;大文字、小文字逆転

DISP:
	mov	dl,al
	mov	ah,2
	int	21h		;表示

	jmp	short START

EXIT:
	mov	ax,4c00h
	int	21h		;終了

	ENDS
	END	START
; 一部のコンパイラでは、
;CODE	ENDS
;	END	START
;と記述しなければいけないようです

練習問題へ　:　 INDEX　:　次の章へ